module Gidl.Backend.Haskell where

import Gidl.Types
import Gidl.Parse
import Gidl.Interface
import Gidl.Backend.Cabal
import Gidl.Backend.Haskell.Types
import Gidl.Backend.Haskell.Test
import Gidl.Backend.Haskell.Interface

import Ivory.Artifact

import Data.Maybe (catMaybes)
import System.Exit (exitFailure, exitSuccess)

haskellBackend :: TypeEnv -> InterfaceEnv -> String -> [String] -> [Artifact]
haskellBackend te@(TypeEnv te') ie@(InterfaceEnv ie') pkgname namespace =
  [ cabalFileArtifact cf
  , makefile
  , artifactPath "tests" serializeTestMod
  ] ++
  [ artifactPath "src" m | m <- sourceMods
  ]
  where
  tmods = [ typeModule (namespace ++ ["Types"]) tr
          | (tn, _t) <- te'
          , let tr = typeDescrToRepr tn te
          , isUserDefined tr
          ]
  imods = [ interfaceModule (namespace ++ ["Interface"]) ir
          | (iname, _i) <- ie'
          , let ir = interfaceDescrToRepr iname ie te
          ]
  sourceMods = tmods ++ imods
  cf = (defaultCabalFile pkgname cabalmods deps) { tests = [ serializeTest ] }
  cabalmods = [ filePathToPackage (artifactFileName m) | m <- sourceMods ]
  deps = [ "cereal", "QuickCheck" ]

  serializeTest = defaultCabalTest "serialize-test" "SerializeTest.hs"
                      (pkgname:deps)
  serializeTestMod = serializeTestModule namespace
                        [ interfaceDescrToRepr iname ie te | (iname, _i) <- ie']


runHaskellBackend :: FilePath -> String -> [String] -> FilePath -> IO ()
runHaskellBackend idlfile pkgname namespace outdir = do
  c <- readFile idlfile
  case parseDecls c of
    Left e -> print e >> exitFailure
    Right (te, ie) -> do
      let as = haskellBackend te ie pkgname namespace
      es <- mapM (putArtifact outdir) as
      case catMaybes es of
        [] -> exitSuccess
        ees -> putStrLn (unlines ees) >> exitFailure